home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
CRS
/
crs03.d81
/
cnna1581.prg
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2009-10-10
|
2KB
|
38 lines
10 PRINT "[147] CHANGE DISKETTE HEADER-NAME"
20 PRINT " DISK UNIT NR (8-15) ?[160]8 [157][157][157][157]";
30 INPUT U: IF U<8 OR U>15 THEN PRINT "[145][145][145]": GOTO 20
40 PRINT " DISK DRIVE NR (0/1) ?[160]0[157][157][157]";
50 INPUT D: IF D<0 OR D>1 THEN PRINT "[145][145][145]": GOTO 40
60 PRINT " PUT TARGET DISK IN UNIT";U;" DRIVE";D
70 PRINT " THEN PRESS ANY KEY TO CONTINUE"
80 GET X$: IF X$=""THEN 80
90 A=1: V=16: Q$=CHR$(34): P$=CHR$(160)
100 T=40: S=0: I$="I"+RIGHT$(STR$(D),1)
110 OPEN 1,U,15,I$: GOSUB 350
120 GOSUB 310: F$=H$: GET#2,X$,X$,A$,B$
130 PRINT "[147] CURRENT HEADER-NAME ";Q$;F$;Q$
140 PRINT " DISKETTE ID IS: ";A$;B$
150 PRINT " NEW NAME (MAX 16 CHARACTERS) OR 'QUIT'"
160 INPUT " ? QUIT[157][157][157][157][157][157]";N$: L=LEN(N$): IF L>V THEN 130
170 IF N$="QUIT" THEN PRINT "[147]";: GOTO 370
180 PRINT " OK TO WRITE NEW HEADER-NAME (Y/N) ? Y[157][157][157]";
190 INPUT X$: IF X$<>"Y" THEN 130
200 IF L=V THEN 220
210 FOR X=L+A TO V: N$=N$+P$: NEXT
220 PRINT#1,"B-P:";2;4: PRINT#2,N$;
230 PRINT#1,"U2:";2;D;T;S: GOSUB 350
240 PRINT#1,I$: GOSUB 350: CLOSE 2
250 PRINT " OLD HEADER-NAME ";Q$;F$;Q$
260 GOSUB 310: CLOSE 2: CLOSE 1
270 PRINT " NEW HEADER-NAME ";Q$;H$;Q$
280 PRINT " CHANGE ANOTHER DISKETTE (Y/N) ? Y[157][157][157]";
290 INPUT X$: IF X$="Y" THEN 60
300 PRINT "[147]";: END
310 OPEN 2,U,2,"#": GOSUB 350: H$=""
320 PRINT#1,"U1:";2;D;T;S: GOSUB 350
330 PRINT#1,"B-P:";2;4: FOR X=A TO V
340 GET#2,T$: H$=H$+T$: NEXT: RETURN
350 INPUT#1,E,M$,J,K:IF E=0 THEN RETURN
360 PRINT " ERROR: ";E;M$;J;K
370 CLOSE 2: CLOSE 1: END